Repository navigation
Expand file tree
/
Copy pathexported-symbols.map
More file actions
71 lines (70 loc) · 3.09 KB
/
Copy pathexported-symbols.map
File metadata and controls
71 lines (70 loc) · 3.09 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
/*
* V8's public API lives directly under v8:: with an uppercase first letter
* (v8::Isolate, v8::Context, ...) while everything private is nested in
* v8::internal::. The split has to be made by case here: lld resolves a symbol
* matched by both a global: and a local: pattern in favour of global:, so the
* internals cannot be carved back out with a "local: v8::internal::*" entry.
*
* The case rule alone is not enough, because inline code in the public headers
* calls out-of-line helpers that live in the private namespaces:
* v8::Object::GetInternalField() reaches
* v8::internal::Internals::GetCurrentIsolate(), every cppgc::Member<T> store
* reaches cppgc::internal::WriteBarrier, MakeGarbageCollected reaches the
* allocation trait. A plugin compiled against the public headers cannot link
* without them, so they are listed one by one below rather than re-admitted as
* v8::internal::* / cppgc::internal::*, which would put tens of thousands of
* symbols back. A name belongs in that group only if an inline body under
* include/ references it -- static data members included, since the barrier and
* pointer-compression fast paths read them directly. Match the whole class, or
* the bare function name followed by *, so an entry survives a signature change
* across a V8 bump.
*
* Patterns must stay unquoted -- a quoted string is matched literally, not as a
* wildcard. An unquoted pattern cannot contain a parenthesis either, so an
* overload set can only be narrowed down to its name, never to one signature.
*/
{
global:
Java_*;
JNI_OnLoad;
napi_*;
node_api_*;
NativeScriptNapiEnv;
extern "C++" {
v8::[A-Z]*;
v8::api_internal::*;
v8::platform::*;
cppgc::[A-Z]*;
v8::internal::CopyTracedReference*;
v8::internal::DisposeTracedReference*;
v8::internal::GlobalizeTracedReference*;
v8::internal::Internals::CheckInitializedImpl*;
v8::internal::Internals::GetCurrentIsolate*;
v8::internal::MoveTracedReference*;
v8::internal::ShouldThrowOnError*;
v8::internal::StrongRootAllocatorBase::*;
v8::internal::VerifyHandleIsNonEmpty*;
cppgc::internal::BaseObjectSizeTrait::*;
cppgc::internal::CageBaseGlobal::*;
cppgc::internal::CagedHeapBase::*;
cppgc::internal::DCheckImpl*;
cppgc::internal::EnsureGCInfoIndexTrait::*;
cppgc::internal::ExplicitManagementImpl::*;
cppgc::internal::Fatal*;
cppgc::internal::MakeGarbageCollectedTraitInternal::*;
cppgc::internal::NameTraitBase::*;
cppgc::internal::PersistentRegion::*;
cppgc::internal::PersistentRegionBase::*;
cppgc::internal::PersistentRegionLock::*;
cppgc::internal::PrefinalizerRegistration::*;
cppgc::internal::SameThreadEnabledCheckingPolicyBase::*;
cppgc::internal::StrongCrossThreadPersistentPolicy::*;
cppgc::internal::StrongPersistentPolicy::*;
cppgc::internal::TraceTraitFromInnerAddressImpl::*;
cppgc::internal::WeakCrossThreadPersistentPolicy::*;
cppgc::internal::WeakPersistentPolicy::*;
cppgc::internal::WriteBarrier::*;
};
local:
*;
};