TTP2/flake.nix at main · Sobottasgithub/TTP2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
{
  description = "Tablo Transfer Protocol 2";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs { inherit system; };

      version = "1.7";

      commonDeps = with pkgs; [
        cmake
        gcc
        gnumake
        libtasn1
      ];

      mkTTP2Package =
        {
          pname,
          buildTarget,
          enableLib ? false,
          enableClient ? false,
          enableServer ? false,
          extraInputs ? [ ],
        }:
        pkgs.stdenv.mkDerivation {
          inherit pname version;
          src = ./.;

          buildInputs = commonDeps ++ extraInputs;

          configurePhase = ''
            cmake -B build -S $src \
              -DCMAKE_BUILD_TYPE=Release \
              -DDEF_TTP2=${if enableLib then "ON" else "OFF"} \
              -DDEF_CLIENT=${if enableClient then "ON" else "OFF"} \
              -DDEF_SERVER=${if enableServer then "ON" else "OFF"}
          '';

          buildPhase = ''
            cmake --build build \
              --target ${buildTarget} \
              -j$NIX_BUILD_CORES
          '';

          installPhase = ''
            cmake --install build --prefix=$out
            cp LICENSE $out/
          '';
        };

    in
    {
      packages.${system} =
        let
          lib = mkTTP2Package {
            pname = "libttp2";
            buildTarget = "ttp2";
            enableLib = true;
          };
        in
        {
          inherit lib;

          client = mkTTP2Package {
            pname = "ttp2-client";
            buildTarget = "ttp2-client";
            enableClient = true;
            extraInputs = [ lib ];
          };

          server = mkTTP2Package {
            pname = "ttp2-server";
            buildTarget = "ttp2-server";
            enableServer = true;
            extraInputs = [ lib ];
          };

          full = mkTTP2Package {
            pname = "libttp2-full";
            buildTarget = "all";
            enableLib = true;
            enableServer = true;
            enableClient = true;
          };

          default = self.packages.${system}.lib;
        };

      devShells.${system}.default = pkgs.mkShell {
        packages = commonDeps ++ [
          pkgs.bridge-utils
          pkgs.clang-tools
        ];

        shellHook = ''
          ./build-asn1-packets.sh
          git status
        '';
      };
    };
}