justfile

mod common '../common.justfile'

USE_UV := env("USE_UV", "false")
VENV_BIN := ".venv/bin/"
PYTHON := VENV_BIN + "python3"
PIP := if USE_UV == "true" { "uv pip" } else { VENV_BIN + "pip" }

_default:
    @just --list

# Install Python dependencies via virtualenv. This is not required for development, but can be used to set up a clean environment for testing.
[arg('module_resolution', pattern='|--resolution=lowest-direct')]
[group("install")]
install module_resolution="": install-venv (install-dependencies "dev,test,examples" module_resolution)

install-uv:
    #!/bin/sh
    if [ -x "$(command -v uv)" ]; then
        echo "uv is already installed"
        exit 0
    fi

    echo "Installing uv..."
    python -m pip install --upgrade pip
    python -m pip install uv

_venv-is-installed:
    @test -d {{ VENV_BIN }} \
    || (echo "Virtual environment not found. Please run 'just python install-venv' to create a virtual environment." && exit 1)

# Create or replace a virtual environment in the .venv directory.
[arg('python-version', long='python')]
[group("install")]
install-venv python-version="": common::_clear
    rm -rf .venv
    {{ if USE_UV == "true" { "uv venv .venv" } else { "python3 -m venv .venv" } }} {{ if python-version == "" { "" } else { "--python " + python-version } }}
    @-echo "To activate the virtual environment, run: source .venv/bin/activate"

# Install dependencies for dev, test and examples. This is required for development and testing.
[arg('features', pattern='dev|test|examples|dev,test|dev,examples|test,examples|dev,test,examples')]
[arg('module_resolution', pattern='|--resolution=lowest-direct')]
[group("install")]
install-dependencies features module_resolution="": common::_clear _venv-is-installed
    {{ PIP }} install {{ module_resolution }} -e ../api-clients/python --config-settings editable_mode=compat
    {{ PIP }} install {{ module_resolution }} -e .[{{ features }}]

# Check if Python code is formatted correctly, check for linting errors and type errors.
[group("lint")]
lint: lint-code lint-tests

# Check if Python code is formatted correctly, check for linting errors and type errors.
[group("lint")]
lint-code: common::_clear _venv-is-installed
    {{ PYTHON }} -m ruff format --check
    {{ PYTHON }} -m ruff check
    {{ PYTHON }} -m mypy geoengine

# Check if Python code is formatted correctly, check for linting errors and type errors.
[group("lint")]
lint-tests: common::_clear _venv-is-installed
    {{ PYTHON }} -m mypy tests

# Build the Python package. The package is built in the dist directory.
[group("build")]
build: common::_clear _venv-is-installed
    {{ PYTHON }} -m build

# Run all Python tests.
[arg("build-type", long="build-type", pattern="debug|release")]
[arg("coverage", long="coverage", value="--cov=geoengine --cov-report=lcov")]
[arg("test-code-path", long="test-code-path")]
[group("test")]
test filter="" test-code-path="../geoengine" build-type="debug" coverage="": common::_clear _venv-is-installed
    GEOENGINE_TEST_CODE_PATH={{ test-code-path }} \
    GEOENGINE_TEST_BUILD_TYPE={{ build-type }} \
    {{ VENV_BIN }}pytest {{ coverage }} {{ if filter == "" { "" } else { "-k '" + filter + "'" } }}

# Run all examples in the examples directory.
[arg("build-type", long="build-type", pattern="debug|release")]
[arg("coverage", long="coverage", value="--cov=geoengine --cov-report=lcov")]
[arg("test-code-path", long="test-code-path")]
[group("test")]
run-examples test-code-path="../geoengine" build-type="debug" coverage="": common::_clear _venv-is-installed
    . {{ VENV_BIN }}activate && \
    GEOENGINE_TEST_CODE_PATH={{ test-code-path }} \
    GEOENGINE_TEST_BUILD_TYPE={{ build-type }} \
    {{ if coverage == "" { "" } else { 'COVERAGE_COMMAND="' + coverage + '"' } }} \
    {{ PYTHON }} test_all_notebooks.py

format-code: common::_clear _venv-is-installed
    {{ PYTHON }} -m ruff format
    {{ PYTHON }} -m ruff check --fix

# Publish the Python client to PyPI. Usage: `just python publish`. Use the `--dry-run` flag to publish to TestPyPI instead.
[arg("dry-run", long="dry-run", value="true", help="Whether to publish to testpypi instead.")]
[group('publish')]
publish dry-run="false": common::_clear
    python -m pip install --upgrade pip twine
    python -m twine upload --repository {{ if dry-run == "true" { "testpypi" } else { "pypi" } }} dist/*