Unable to get Terminal Size error

[scottchiefbaker]

I'm getting this error when in Dump::Krumo:

Unable to get Terminal Size. The TIOCGWINSZ ioctl didn't work. The COLUMNS and LINES environment variables didn't work. The resize program didn't work. The stty program didn't work. at /home/bakers/perl5/lib/perl5/Dump/Krumo.pm line 738.

I'm guessing for some reason there is not TTY attached and this is TRK's way of saying that? I'm trying to work around this by falling back to tput

sub get_terminal_width {
    my @x;
    my $width;
    my $ok = 0;

    eval {
        @x  = Term::ReadKey::GetTerminalSize();
        $ok = 1;
    };
    my $err_msg = $@;

    # If there was an error with the eval fallback to tput
    if ($ok) {
        $width = $x[0];
    } else {
        $width = `tput cols`;
    }

    $width = int($width);

    return $width;
}

I'm still getting this error, even with the code inside of an eval. Can you shed any light on where I should troubleshoot next?

[jonathanstowe]

If the process isn't attached to a terminal it won't be able to get the terminal size. I'm at a loss as I don't know what Dump::Krumo is or what it does.

In a "normal" terminal all those things should work:

 jonathan@menenius:~/working/NAP/pandora$ perl -MTerm::ReadKey -Mfeature=say -e 'say join ",", Term::ReadKey::GetTerminalSize();' 
141,31,0,0
jonathan@menenius:~/working/NAP/pandora$ echo $COLUMNS, $LINES
141, 31
jonathan@menenius:~/working/NAP/pandora$ tput cols
141

[scottchiefbaker]

Is there a way I can work around the error message above? It'd be nice if it just returned zero so I can have a sensible fallback.

I'm running this code in my scenario:

sub get_terminal_width {
    my $tput  = $ENV{COLUMNS} || -1;
    my $width = `tput cols`;

    use Term::ReadKey;
    my @trk = Term::ReadKey::GetTerminalSize();

    $width = int($width) || 80;
    print "TPUT WIDTH : $width\n";
    print "ENVIRONMENT: $tput\n";
    print "Term::RK   : $trk[0]\n";

    return $width;
}

and I see this output:

Unable to get Terminal Size. The TIOCGWINSZ ioctl didn't work. The COLUMNS and LINES environment variables didn't work. The resize program didn't work. The stty program didn't work. at /home/bakers/perl5/lib/perl5/Dump/Krumo.pm line 736.
Use of uninitialized value $trk[0] in concatenation (.) or string at /home/bakers/perl5/lib/perl5/Dump/Krumo.pm line 741.
TPUT WIDTH : 156
ENVIRONMENT: 156
Term::RK   :

Why would tput and environment variables work, when TRK doesn't?

I'm running v2.38 if it helps.

[jonathanstowe]

As it stands it isn't possible to shut up the warning as GetTerminalSize basically tries all the available methods and if none work then it will carp with the lost of all the methods tried and failed. eval won't catch that as it isn't dieing but simply warning (carp being a fancy warn basically.) That said you can make the output of carp go away temporarily with something like:

my @size;
{
   local *STDERR;
   open STDERR, '>', '/dev/null';
   @size =  Term::ReadKey::GetTerminalSize();
}

Obviously whether that is appropriate in your code is another matter.

The real question is what kind of environment it is being run in that STDOUT isn't terminal-like enough for the ioctl not to work. It's trivial to replicate in docker without a terminal allocated:

jonathan@menenius:~/devel/modules/TermReadKey$ docker exec amq-dc1 perl -MTerm::ReadKey -e 'print join ",", Term::ReadKey::GetTerminalSize()'
Unable to get Terminal Size. The TIOCGWINSZ ioctl didn't work. The COLUMNS and LINES environment variables didn't work. The resize program didn't work. The stty program didn't work. at -e line 1.

vs

jonathan@menenius:~/devel/modules/TermReadKey$ docker exec -t amq-dc1 perl -MTerm::ReadKey -e 'print join ",", Term::ReadKey::GetTerminalSize()'
178,24,0,0

If that is an anticipated situation then you can skip trying the GetTerminalSize altogether with something like:

my @size;
if ( -t STDOUT ) {
   @size =  Term::ReadKey::GetTerminalSize();
}

There are other ways a process can arrange to completely detach from a terminal.

If you look in the t/02_terminal_functions.t you can see how similar is being used there; the tests being run in docker by Github actions.

I haven't a clue as to why tput cols would work and GetTerminalSize not as both basically wind up doing the same:

ioctl(2, TIOCGWINSZ, {ws_row=24, ws_col=178, ws_xpixel=0, ws_ypixel=0})

(stty does similar but tries harder to get a usable file handle for a tty.)

So it boils down to the details of the environment it is running in when it behaves like that.