configure.ac: detect unusable termio operations

Some termio operations are not actually usable on some
architectures. For example, the TCGETA, TCSETA, TCSETAF and TCSETAW
are defined with a reference to "struct termio" on alpha, hppa and
sparc64, but "struct termio" is no longer defined since glibc 2.42,
causing a build failure.

Instead of using those operations as soon as they are defined, this
commit checks more carefully that they are actually usable. This is
done using a new m4 macro PY_CHECK_IOCTL.

Signed-off-by: Thomas Petazzoni <[email protected]>

Author: tpetazzoni

Modules/termios.c

@@ -1116,7 +1116,7 @@ static struct constant {
 #ifdef TCFLSH
     {"TCFLSH", TCFLSH},
 #endif
-#ifdef TCGETA
+#if defined(HAVE_TCGETA)
     {"TCGETA", TCGETA},
 #endif
 #ifdef TCGETS
@@ -1128,13 +1128,13 @@ static struct constant {
 #ifdef TCSBRKP
     {"TCSBRKP", TCSBRKP},
 #endif
-#ifdef TCSETA
+#if defined(HAVE_TCSETA)
     {"TCSETA", TCSETA},
 #endif
-#ifdef TCSETAF
+#if defined(HAVE_TCSETAF)
     {"TCSETAF", TCSETAF},
 #endif
-#ifdef TCSETAW
+#if defined(HAVE_TCSETAW)
     {"TCSETAW", TCSETAW},
 #endif
 #ifdef TCSETS

configure.ac

@@ -95,6 +95,26 @@ AC_DEFUN([PY_CHECK_EMSCRIPTEN_PORT], [
   AS_VAR_POPDEF([py_libs])
 ])
 
+dnl PY_CHECK_IOCTL(IOCTL_SYMBOL)
+AC_DEFUN([PY_CHECK_IOCTL],
+[
+  AC_MSG_CHECKING([for $1])
+  AC_COMPILE_IFELSE(
+    [AC_LANG_PROGRAM(
+       [[#include <sys/ioctl.h>]],
+       [[
+         /* Test whether $1 is declared */
+         long val = $1;
+         return 0;
+       ]]
+     )],
+    [AC_MSG_RESULT([yes])
+     AC_DEFINE([HAVE_$1], [1],
+               [Define this if $1 termio operation is usable])],
+    [AC_MSG_RESULT([no])]
+  )
+])
+
 AC_SUBST([BASECPPFLAGS])
 if test "$srcdir" != . -a "$srcdir" != "$(pwd)"; then
     # If we're building out-of-tree, we need to make sure the following
@@ -8245,6 +8265,12 @@ AC_SUBST([JIT_STENCILS_H])
 # substitute multiline block, must come after last PY_STDLIB_MOD()
 AC_SUBST([MODULE_BLOCK])
 
+# ioctls used by Modules/termios.c but not usable on all platforms
+PY_CHECK_IOCTL([TCGETA])
+PY_CHECK_IOCTL([TCSETA])
+PY_CHECK_IOCTL([TCSETAF])
+PY_CHECK_IOCTL([TCSETAW])
+
 # generate output files
 AC_CONFIG_FILES(m4_normalize([
   Makefile.pre